FGALDC 14
/RE:07092 RE^5:HTM2TXT.DEFへの葬送

　こんにちは、としき さん、自己レスです。

》それに、試してみたけど、実行速度はあんまり早くはなかったなぁ。

これ、なぜ遅いかというと、多分１文字毎に #W #W しているからでしょう。
ということで、１行毎に出力するバージョンを作ってみました。

==== htm2text.def ====
■html 文書整形
■vwx 常駐（？）
* M
1 ^V "htm2text.def"
        ?.
        &s
        &#M(4) #^ #<
        mb-,ew[-,ec[+,zh[-,ps[=pw,mp[,Ei[-,ux+,c=0,
        mr255,
        &00 d=r,
        
        #N #P ux[+,#16 ux],"TXT" #m
        #W
        
:A
        (cd=='<')?{
                #d #G
;                &So(ps,"/")(r==ps)?{&10}
                &So(ps,"BR")(r==ps)?{a=13,&95 &01 >D}
                &So(ps,"P")(r==ps)?{a=13,&95 &01 >D}
                &01
                >D
        }
        (cd=='&')?{
                #d #G
                &SO(ps,"quot")(r==ps)?{a='&',&95}
                &SO(ps,"lt")(r==ps)?{a='<',&95}
                :C (cd!=';')?{#d (r)??>C}
                >D
        }
        a=cd,(a==10||a==13)?a=' ', (a==' ' && b==' ')?>D
        &95
:D      #d (r)??>A
        &d
        &#U(4) #W #^
        ux-,Ei],mp],ps],zh],ec],ew],mb-,

10:
        #d #G
        &So(ps,"P")(r==ps)?{a=13,&95}
        :X (cd!='>')?{#d (r)??>X}

95:     ;IN:a 
        (a==13)?{
                (b!=13)?{#W &?("%s",d) #m #W c=0,}
        }?{
                &Sp((d+c),"%c",a)
                (ck==0)?{c++,}?{c+=2,}
                (c>we-3)?{d.c=0,#W &?("%s",d) #m #W c=0,}
        }
        b=a,

00:     (3+$). "$[256]"
01:     :A (cd!='>')?{#d (r)??>A}        ;タグ末尾までカーソル移動

*
===

おお、かなり速くなってる。
どのくらい速くなっているか、ちょっと測定してみました。

対象ＨＴＭＬファイル：とある小説
ファイルサイズ　　　：175870 BYTE
論理行数　　　　　　：  5781
タグ数　　　　　　　：  9448


HOTMILK
01/02/17 (土) 09:32:50
01/02/17 (土) 09:33:39
４９秒
ただし、途中に改行の入っているタグ（約３０００個）は削除してくれない

HTM2TXT（オリジナル）
改行変換の部分でラインバッファを超過するためかハングアップ

HTM2TXT（としき改竄版）
01/02/16 (金) 23:39:10
01/02/16 (金) 23:41:09
１分５９秒

HTM2TEXT（#7092版）
01/02/17 (土) 09:48:20
01/02/17 (土) 09:49:10
５０秒

HTM2TEXT（上記）
01/02/17 (土) 09:29:18
01/02/17 (土) 09:29:42
２４秒

うひょひょうひょひょ。ﾍ(^^ﾍ)(ﾉ^^)ﾉﾍ(^^ﾍ)(ﾉ^^)ﾉ

今後、いろいろとくっつけていくから、当然もっと遅くなると思うけど、とりあ
えず HOTMILK には負けないようにがんばろっと。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　としき